***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 26, 2026                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P2AL5P0A-AU  A K 
.param
+vc0 = 2.106e-11	vc1 = 4.856e-11		vc2 = 1.000		vc3 = 3.075e-14		vc4 = 2.749
+tc1 = 3.081e-2		tc2 = 1.711e-2		tc3 = 6.701e-3		tc4 = 1.061e-2
d1  A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {3.257e-2*min(i,0)}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 4.035e-15	  n = 0.995		 rs = 1.698e-2
+ibv = 1.000e-2	        nbv = 1.000	         bv = 6.7
+ikf = 3.026e1
***** capacitance parameter *****
+cjo = 1.259e-9		  m = 3.396e-1		 vj = 7.145e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		 eg = 1.065	        xti = 3
+trs1 = -1.500e-3      tikf = -1.000e-3
+tbv1 = 3.270e-4       tbv2 = 5.986e-7	
.ends P2AL5P0A-AU
*$
